Jalaj P. Jha » Functions

The Blog Revisited – 8

Jalaj — Wed, 21 Nov 2007 13:23:37 +0000

Three of the posts in May were related to MS Project, discussing scheduling of tasks and setting deadlines and constraints.

With my previous insight on how Technorati fails to detect pages from same blog, I got prepared to go deeper into it's perceived algorithm and just then Technorati saw some changes (not the expected ones) and I dropped my plans to go ahead. There is Something about Technorati and Technorati Rank is Dead (It rose again from undead...) were two posts on Technorati.

May saw a very good event for me, getting verified by Google for Webmaster Tools, which I later found it to be undocumented on web and thus came up the post Get your Wordpress.com Blog Google Verified which saw a large number of views, and is still referred.

It was then that I decided to get my own domain. The decision was sudden as is documented at Wordpress.com Domain Upgrade... though later I felt regretting the decision as the Toolbar update get unexpectedly delayed which also disturbed the traffic to the blog and later in posting frequency.

Below are some more posts on Google reviewing it's new features.

May also saw last posts on WinAPI (though I have not given up yet)

Social Engineering was a post that details how anyone can get cheated by someone, who not even need to be a pro hacker.

Many of you might have frequently received powerpoint PPS files in mails as attachement. Many a times you might have felt prompted to edit a file to your own convenience but alas... PPS files are not editable... Don't worry see how you can easily Convert PPS to PPT

The Blog Revisited – 7

Jalaj — Fri, 16 Nov 2007 04:46:51 +0000

Databases allow datatypes that can store unicode data, then why was it that while MS-Access successfully stored Unicode data whereas MS-SQL server failed when I first tried. See how to handle Unicode data in Storing Unicode Data in Databases.

After of years of existence of internet most of the dictionary words domain seem to have been already taken. Do you too think so? Check for words from your regional language dictionary as domain names need not necessarily be ASCII one but can be any language text in Unicode. For details see

IME (or Input Method Editor) is an excellent way to type in Regional language text. But what to you do when a few text boxes expect English inputs while others regional inputs... do you need to switch IME on and off every now and then. Not if the software you develop takes care of automatic switching. Switching IME during runtime details how to achieve automatic switching of IME.

Most multilingual softwares allow you to set language options but require you to restart application before language change is effective. If you need immediate UI language change Changing UI Language during Runtime is one of the way to do it.

But what if the two languages you aer switching have different orientation of RTL (Right to Left) and LTR(Left to Right)? Mirroring Form for RTL languages as Arabic detilas how you can switch control locations.

Google Translate gives you facility to translate selected text or entire page between available languages. You can use JavaScript to provide translation button on your site/blog to translate current the current page details of which is here at Google Translate

Google Desktop supports interface in many languages. Google Desktop Now in Hindi came when Hindi language interface was added.

Google Reader allows you to send selected posts from RSS feed you read to your friends or share them and publish as RSS feed for others to subscribe. Read about these in More reasons to use Google Reader

After a long gap since my last post on Microsoft Project came MS Project : Define General Working Time that shows how calendar can be modified globally or resourse-wise.

Get into Technorati Top 100 in 24 Hours was the first post that brought this blog in Growing Blogs list of botd.wordpress.com. "in 24 hours" is just for attracting attention. Applying that in the timeframe may be practical but you cannot get away without getting banned by Technorati... But since Technorati never ever seemed to resolve this problem, you can easily exploit it to get higher rank by avoiding attracting attention.

WinAPI functions saw a slowdown in terms of posts on this blog and subsequent two post were WinAPI : DrawText & DrawTextEx and WinAPI : The Font Object

Google rebranded it's "personalized homepage" as iGoogle. What’s in a Name?

5th of February was called for as a CSS "edun" day (read quoted text in reverse, I don't feel eager to categorize my site for "tluda" content ) where all blogs were asked to remove CSS for a day. Having upgraded to Custom CSS I had the option to do so. No CSS on 5th April.

Microsoft came up with SilverLight to compete with Flash. Read about it here at Flash plus more with Microsoft Silverlight. I haven't looked back if it really succeeded or not.

The Flash Chart on Wordpress.com Dashboard are attractive and useful. See where did it originated in Flash Charts

New Features on Wordpress.com was update on new features added to wordpress.com and Twice the categories was reporting of a bug there.

Last 30 days and Last 30 Days were stats for April and May, Ashirwad-project.org was announcement of a new blog.

Font Enumeration Application

Jalaj — Mon, 28 May 2007 14:37:38 +0000

In the previous post in WinAPI series, WinAPI : Enumerating Installed Fonts, EnumFontFamiliesEx function was detailed which allows us to get info on all fonts installed in the system. Let's workout a application on the same.

Create a new Visual Basic project. Create a list box named List1, and change it's "Sorted" property to True. Now create a new module. Unless stated all the code mentioned will be required to be placed in this module.

Declare the EnumFontFamiliesEx function and relevant Constants and Structures as below.

Public Declare Function EnumFontFamiliesEx Lib "gdi32" Alias "EnumFontFamiliesExA" ( _
    ByVal hDC As Long, lpLogFont As LOGFONT, ByVal lpEnumFontProc As Long, _
    ByVal lParam As Long, ByVal dw As Long) As Long

Public Const LF_FACESIZE = 32
Public Const LF_FULLFACESIZE = 64

Public Type NEWTEXTMETRIC
        tmHeight As Long
        tmAscent As Long
        tmDescent As Long
        tmInternalLeading As Long
        tmExternalLeading As Long
        tmAveCharWidth As Long
        tmMaxCharWidth As Long
        tmWeight As Long
        tmOverhang As Long
        tmDigitizedAspectX As Long
        tmDigitizedAspectY As Long
        tmFirstChar As Byte
        tmLastChar As Byte
        tmDefaultChar As Byte
        tmBreakChar As Byte
        tmItalic As Byte
        tmUnderlined As Byte
        tmStruckOut As Byte
        tmPitchAndFamily As Byte
        tmCharSet As Byte
        ntmFlags As Long
        ntmSizeEM As Long
        ntmCellHeight As Long
        ntmAveWidth As Long
End Type

Public Type FONTSIGNATURE
        fsUsb(4) As Long
        fsCsb(2) As Long
End Type

Public Type LOGFONT
        lfHeight As Long
        lfWidth As Long
        lfEscapement As Long
        lfOrientation As Long
        lfWeight As Long
        lfItalic As Byte
        lfUnderline As Byte
        lfStrikeOut As Byte
        lfCharSet As Byte
        lfOutPrecision As Byte
        lfClipPrecision As Byte
        lfQuality As Byte
        lfPitchAndFamily As Byte
        lfFaceName(1 To LF_FACESIZE) As Byte
End Type

Public Type ENUMLOGFONTEX
        elfLogFont As LOGFONT
        elfFullName(LF_FULLFACESIZE) As Byte
        elfStyle(LF_FACESIZE) As Byte
        elfScript(LF_FACESIZE) As Byte
End Type

Public Type NEWTEXTMETRICEX
        ntmTm As NEWTEXTMETRIC
        ntmFontSig As FONTSIGNATURE
End Type

The EnumFontFamiliesEx function once called sends all details to callback function EnumFontFamExProc. So let's declare the function. We would be adding more code to this function later.

Public Function EnumFontFamExProc(ByRef lpELFX As ENUMLOGFONTEX, _
    ByRef lpNTME As NEWTEXTMETRICEX, ByVal lFontType As Long, _
    ByVal lParam As Long) As Long

End Function

Now in the code section of Form place the code in the Load event of form. This will make a call to EnumFontFamiliesEx function.

Private Sub Form_Load()

    Dim objlogfont As LOGFONT
    EnumFontFamiliesEx Form1.hDC, objlogfont, AddressOf EnumFontFamExProc, 0, 0

End Sub

Now once the EnumFontFamiliesEx function has been called, callback function EnumFontFamExProc will start getting the font details one at a time. Let's first aim at getting all font names and fill them in the listbox List1. Place the code below within the callback function. Since the Font's face name is received as a byteArray we will loop through the 32 bytes and exit when a Null character is encountered. EnumFontFamExProc callback function continues to get data until all fonts have been enumerated or until the callback function returns false (non-zero), hence we have made the function to return 1 on each call.

    Dim ctr As Integer
    Dim sFaceName As String

    sFaceName = ""

    For ctr = 1 To LF_FACESIZE
        If lpELFX.elfLogFont.lfFaceName(ctr) = 0 Then
            Exit For
        Else
            sFaceName = sFaceName & Chr(lpELFX.elfLogFont.lfFaceName(ctr))
        End If
    Next

    Form1.List1.AddItem sFaceName

    EnumFontFamExProc = 1

Execute the application and find all fonts installed on the system listed in the listbox. That ends the first part of our application.

Now let's add some more functionality using the data that we receive with callback and work on a problem that used to haunt me more often "How to find which Unicode Scripts a font supports?". As described earlier this information is available with the fsUsb member of the FONTSIGNATURE structure.

fsUsb is an array for four Longs, capable of identifying upto 126 Unicode Subranges as defined in ISO 10646 standard. We would here check for the 91 unicode Subranges for which let's create an array carrying the names of the subranges. Add the code below to the module.

Public Const MAXSUBRANGELISTEDHERE As Integer = 90

Public UnicodeSubRange(0 To MAXSUBRANGELISTEDHERE) As String

Public Sub PrepareSubRange()

    UnicodeSubRange(0) = "Basic Latin"
    UnicodeSubRange(1) = "Latin-1 Supplement"
    UnicodeSubRange(2) = "Latin Extended-A"
    UnicodeSubRange(3) = "Latin Extended-B"
    UnicodeSubRange(4) = "IPA Extensions"
    UnicodeSubRange(5) = "Spacing Modifier Letters"
    UnicodeSubRange(6) = "Combining Diacritical Marks"
    UnicodeSubRange(7) = "Greek and Coptic"
    UnicodeSubRange(8) = "Reserved"
    UnicodeSubRange(9) = "Cyrillic"
    UnicodeSubRange(10) = "Armenian"
    UnicodeSubRange(11) = "Basic Hebrew"
    UnicodeSubRange(12) = "Reserved"
    UnicodeSubRange(13) = "Basic Arabic"
    UnicodeSubRange(14) = "Reserved"
    UnicodeSubRange(15) = "Devanagari"
    UnicodeSubRange(16) = "Bengali"
    UnicodeSubRange(17) = "Gurmukhi"
    UnicodeSubRange(18) = "Gujarati"
    UnicodeSubRange(19) = "Oriya"
    UnicodeSubRange(20) = "Tamil"
    UnicodeSubRange(21) = "Telugu"
    UnicodeSubRange(22) = "Kannada"
    UnicodeSubRange(23) = "Malayalam"
    UnicodeSubRange(24) = "Thai"
    UnicodeSubRange(25) = "Lao"
    UnicodeSubRange(26) = "Georgian"
    UnicodeSubRange(27) = "Reserved"
    UnicodeSubRange(28) = "Hangul Jamo"
    UnicodeSubRange(29) = "Latin Extended Additional"
    UnicodeSubRange(30) = "Greek Extended"
    UnicodeSubRange(31) = "General Punctuation"
    UnicodeSubRange(32) = "Subscripts and Superscripts"
    UnicodeSubRange(33) = "Currency Symbols"
    UnicodeSubRange(34) = "Combining Diacritical Marks for Symbols"
    UnicodeSubRange(35) = "Letter-like Symbols"
    UnicodeSubRange(36) = "Number Forms"
    UnicodeSubRange(37) = "Arrows"
    UnicodeSubRange(38) = "Mathematical Operators"
    UnicodeSubRange(39) = "Miscellaneous Technical"
    UnicodeSubRange(40) = "Control Pictures"
    UnicodeSubRange(41) = "Optical Character Recognition"
    UnicodeSubRange(42) = "Enclosed Alphanumerics"
    UnicodeSubRange(43) = "Box Drawing"
    UnicodeSubRange(44) = "Block Elements"
    UnicodeSubRange(45) = "Geometric Shapes"
    UnicodeSubRange(46) = "Miscellaneous Symbols"
    UnicodeSubRange(47) = "Dingbats"
    UnicodeSubRange(48) = "Chinese, Japanese, and Korean (CJK) Symbols and Punctuation"
    UnicodeSubRange(49) = "Hiragana"
    UnicodeSubRange(50) = "Katakana"
    UnicodeSubRange(51) = "Bopomofo"
    UnicodeSubRange(52) = "Hangul Compatibility Jamo"
    UnicodeSubRange(53) = "Reserved"
    UnicodeSubRange(54) = "Enclosed CJK Letters and Months"
    UnicodeSubRange(55) = "CJK Compatibility"
    UnicodeSubRange(56) = "Hangul"
    UnicodeSubRange(57) = "Surrogates"
    UnicodeSubRange(58) = "Reserved"
    UnicodeSubRange(59) = "CJK Unified Ideographs"
    UnicodeSubRange(60) = "Private Use Area"
    UnicodeSubRange(61) = "CJK Compatibility Ideographs"
    UnicodeSubRange(62) = "Alphabetic Presentation Forms"
    UnicodeSubRange(63) = "Arabic Presentation Forms-A"
    UnicodeSubRange(64) = "Combining Half Marks"
    UnicodeSubRange(65) = "CJK Compatibility Forms"
    UnicodeSubRange(66) = "Small Form Variants"
    UnicodeSubRange(67) = "Arabic Presentation Forms-B"
    UnicodeSubRange(68) = "Halfwidth and Fullwidth Forms"
    UnicodeSubRange(69) = "Specials"
    UnicodeSubRange(70) = "Tibetan"
    UnicodeSubRange(71) = "Syriac"
    UnicodeSubRange(72) = "Thaana"
    UnicodeSubRange(73) = "Sinhala"
    UnicodeSubRange(74) = "Myanmar"
    UnicodeSubRange(75) = "Ethiopic"
    UnicodeSubRange(76) = "Cherokee"
    UnicodeSubRange(77) = "Canadian Aboriginal Syllabics"
    UnicodeSubRange(78) = "Ogham"
    UnicodeSubRange(79) = "Runic"
    UnicodeSubRange(80) = "Khmer"
    UnicodeSubRange(81) = "Mongolian"
    UnicodeSubRange(82) = "Braille"
    UnicodeSubRange(83) = "Yi"
    UnicodeSubRange(84) = "Tagalog"
    UnicodeSubRange(85) = "Old Italic"
    UnicodeSubRange(86) = "Gothic"
    UnicodeSubRange(87) = "Deseret"
    UnicodeSubRange(88) = "Byzantine Musical Symbols"
    UnicodeSubRange(89) = "Mathematical Alphanumeric Symbols"
    UnicodeSubRange(90) = "Private Use (Plane 15)"

End Sub

Since we have initialized all Subrange names in a subroutine we need to call it on Load event of the form. Add the line below to the Load event of the Form.

    Call PrepareSubRange

Add another listbox List2 on the form. Our aim is that when a font is selected from List1 the Unicode Subranges, whose glyphs are present in the font, should get listed in this new listbox. This has one concern that the FONTSIGNATURE structure for the font is available when the callback function is called. If we need to use those, the same must be preserved while processing the callback. Let's store them in an array. Signature is the array where we would be storing the fsUsb and FontCtr is the counter which will store the number of fonts that have been processed.

Public Signature() As Variant
Public FontCtr As Long

Add the following code at the end of the callback function. The Signature array is redimensioned on each callback, font name and fsUsb is stored and the FontCtr is incremented by 1.

    If FontCtr > 0 Then
        ReDim Preserve Signature(0 To 1, 0 To FontCtr + 1)
    Else
        ReDim Signature(0 To 1, 0 To 0)
    End If

    Signature(0, FontCtr) = sFaceName
    Signature(1, FontCtr) = lpNTME.ntmFontSig.fsUsb
    FontCtr = FontCtr + 1

Now once the required information has been saved, we just require to use it when the selection in the List1 changes to populate the List2. Let's code this functionality in a separate subroutine named "PopulateList2" and call this subroutine from the Click event of the List1. Add the following line to the Click event of the List1 in the Form.

Private Sub List1_Click()

    Call PopulateList2

End Sub

Now for the last part the PopulateList2 subroutine. This clears the List2. It then searches for the Font Name (as selected in the List1) in the Signature array and stores the corresponding fsUsb array in the variable vSig. It then runs through the complete list of Unicode SubRanges and uses Bitwise operations to check if the glyphs for the subrange exist in the font or not. If present, populates the List2 with the corresponding SubRange name.

Public Sub PopulateList2()

    Dim vSig As Variant
    Dim p As Integer
    Dim q As Integer
    Dim ctr As Integer

    Form1.List2.Clear

    For ctr = 0 To UBound(Signature, 2)
        If Signature(0, ctr) = Form1.List1.Text Then Exit For
    Next

    vSig = Signature(1, ctr)

    For ctr = 0 To MAXSUBRANGELISTEDHERE
        p = Int(ctr / 32)
        q = ctr Mod 32

        If q <> 31 Then
            If vSig(p) And 2 ^ q Then
                Form1.List2.AddItem UnicodeSubRange(ctr)
            End If
        Else
            If vSig(p) < 0 Then
                Form1.List2.AddItem UnicodeSubRange(ctr)
            End If
        End If
    Next

End Sub

And that completes our application. The complete Source code is repeated below to facilitate direct copy/paste.

Code in Form1

Private Sub Form_Load()

    Dim objlogfont As LOGFONT
    Call PrepareSubRange
    EnumFontFamiliesEx Form1.hDC, objlogfont, AddressOf EnumFontFamExProc, 0, 0

End Sub

Private Sub List1_Click()

    Call PopulateList2

End Sub

Code in Module1

Option Explicit

Public Declare Function EnumFontFamiliesEx Lib "gdi32" Alias "EnumFontFamiliesExA" ( _
    ByVal hDC As Long, lpLogFont As LOGFONT, ByVal lpEnumFontProc As Long, _
    ByVal lParam As Long, ByVal dw As Long) As Long

Public Const MAXSUBRANGELISTEDHERE As Integer = 90
Public Const LF_FACESIZE = 32
Public Const LF_FULLFACESIZE = 64

Public UnicodeSubRange(0 To MAXSUBRANGELISTEDHERE) As String
Public Signature() As Variant
Public FontCtr As Long

Public Type NEWTEXTMETRIC
        tmHeight As Long
        tmAscent As Long
        tmDescent As Long
        tmInternalLeading As Long
        tmExternalLeading As Long
        tmAveCharWidth As Long
        tmMaxCharWidth As Long
        tmWeight As Long
        tmOverhang As Long
        tmDigitizedAspectX As Long
        tmDigitizedAspectY As Long
        tmFirstChar As Byte
        tmLastChar As Byte
        tmDefaultChar As Byte
        tmBreakChar As Byte
        tmItalic As Byte
        tmUnderlined As Byte
        tmStruckOut As Byte
        tmPitchAndFamily As Byte
        tmCharSet As Byte
        ntmFlags As Long
        ntmSizeEM As Long
        ntmCellHeight As Long
        ntmAveWidth As Long
End Type

Public Type FONTSIGNATURE
        fsUsb(4) As Long
        fsCsb(2) As Long
End Type

Public Type LOGFONT
        lfHeight As Long
        lfWidth As Long
        lfEscapement As Long
        lfOrientation As Long
        lfWeight As Long
        lfItalic As Byte
        lfUnderline As Byte
        lfStrikeOut As Byte
        lfCharSet As Byte
        lfOutPrecision As Byte
        lfClipPrecision As Byte
        lfQuality As Byte
        lfPitchAndFamily As Byte
        lfFaceName(1 To LF_FACESIZE) As Byte
End Type

Public Type ENUMLOGFONTEX
        elfLogFont As LOGFONT
        elfFullName(LF_FULLFACESIZE) As Byte
        elfStyle(LF_FACESIZE) As Byte
        elfScript(LF_FACESIZE) As Byte
End Type

Public Type NEWTEXTMETRICEX
        ntmTm As NEWTEXTMETRIC
        ntmFontSig As FONTSIGNATURE
End Type

Public Sub PrepareSubRange()

    UnicodeSubRange(0) = "Basic Latin"
    UnicodeSubRange(1) = "Latin-1 Supplement"
    UnicodeSubRange(2) = "Latin Extended-A"
    UnicodeSubRange(3) = "Latin Extended-B"
    UnicodeSubRange(4) = "IPA Extensions"
    UnicodeSubRange(5) = "Spacing Modifier Letters"
    UnicodeSubRange(6) = "Combining Diacritical Marks"
    UnicodeSubRange(7) = "Greek and Coptic"
    UnicodeSubRange(8) = "Reserved"
    UnicodeSubRange(9) = "Cyrillic"
    UnicodeSubRange(10) = "Armenian"
    UnicodeSubRange(11) = "Basic Hebrew"
    UnicodeSubRange(12) = "Reserved"
    UnicodeSubRange(13) = "Basic Arabic"
    UnicodeSubRange(14) = "Reserved"
    UnicodeSubRange(15) = "Devanagari"
    UnicodeSubRange(16) = "Bengali"
    UnicodeSubRange(17) = "Gurmukhi"
    UnicodeSubRange(18) = "Gujarati"
    UnicodeSubRange(19) = "Oriya"
    UnicodeSubRange(20) = "Tamil"
    UnicodeSubRange(21) = "Telugu"
    UnicodeSubRange(22) = "Kannada"
    UnicodeSubRange(23) = "Malayalam"
    UnicodeSubRange(24) = "Thai"
    UnicodeSubRange(25) = "Lao"
    UnicodeSubRange(26) = "Georgian"
    UnicodeSubRange(27) = "Reserved"
    UnicodeSubRange(28) = "Hangul Jamo"
    UnicodeSubRange(29) = "Latin Extended Additional"
    UnicodeSubRange(30) = "Greek Extended"
    UnicodeSubRange(31) = "General Punctuation"
    UnicodeSubRange(32) = "Subscripts and Superscripts"
    UnicodeSubRange(33) = "Currency Symbols"
    UnicodeSubRange(34) = "Combining Diacritical Marks for Symbols"
    UnicodeSubRange(35) = "Letter-like Symbols"
    UnicodeSubRange(36) = "Number Forms"
    UnicodeSubRange(37) = "Arrows"
    UnicodeSubRange(38) = "Mathematical Operators"
    UnicodeSubRange(39) = "Miscellaneous Technical"
    UnicodeSubRange(40) = "Control Pictures"
    UnicodeSubRange(41) = "Optical Character Recognition"
    UnicodeSubRange(42) = "Enclosed Alphanumerics"
    UnicodeSubRange(43) = "Box Drawing"
    UnicodeSubRange(44) = "Block Elements"
    UnicodeSubRange(45) = "Geometric Shapes"
    UnicodeSubRange(46) = "Miscellaneous Symbols"
    UnicodeSubRange(47) = "Dingbats"
    UnicodeSubRange(48) = "Chinese, Japanese, and Korean (CJK) Symbols and Punctuation"
    UnicodeSubRange(49) = "Hiragana"
    UnicodeSubRange(50) = "Katakana"
    UnicodeSubRange(51) = "Bopomofo"
    UnicodeSubRange(52) = "Hangul Compatibility Jamo"
    UnicodeSubRange(53) = "Reserved"
    UnicodeSubRange(54) = "Enclosed CJK Letters and Months"
    UnicodeSubRange(55) = "CJK Compatibility"
    UnicodeSubRange(56) = "Hangul"
    UnicodeSubRange(57) = "Surrogates"
    UnicodeSubRange(58) = "Reserved"
    UnicodeSubRange(59) = "CJK Unified Ideographs"
    UnicodeSubRange(60) = "Private Use Area"
    UnicodeSubRange(61) = "CJK Compatibility Ideographs"
    UnicodeSubRange(62) = "Alphabetic Presentation Forms"
    UnicodeSubRange(63) = "Arabic Presentation Forms-A"
    UnicodeSubRange(64) = "Combining Half Marks"
    UnicodeSubRange(65) = "CJK Compatibility Forms"
    UnicodeSubRange(66) = "Small Form Variants"
    UnicodeSubRange(67) = "Arabic Presentation Forms-B"
    UnicodeSubRange(68) = "Halfwidth and Fullwidth Forms"
    UnicodeSubRange(69) = "Specials"
    UnicodeSubRange(70) = "Tibetan"
    UnicodeSubRange(71) = "Syriac"
    UnicodeSubRange(72) = "Thaana"
    UnicodeSubRange(73) = "Sinhala"
    UnicodeSubRange(74) = "Myanmar"
    UnicodeSubRange(75) = "Ethiopic"
    UnicodeSubRange(76) = "Cherokee"
    UnicodeSubRange(77) = "Canadian Aboriginal Syllabics"
    UnicodeSubRange(78) = "Ogham"
    UnicodeSubRange(79) = "Runic"
    UnicodeSubRange(80) = "Khmer"
    UnicodeSubRange(81) = "Mongolian"
    UnicodeSubRange(82) = "Braille"
    UnicodeSubRange(83) = "Yi"
    UnicodeSubRange(84) = "Tagalog"
    UnicodeSubRange(85) = "Old Italic"
    UnicodeSubRange(86) = "Gothic"
    UnicodeSubRange(87) = "Deseret"
    UnicodeSubRange(88) = "Byzantine Musical Symbols"
    UnicodeSubRange(89) = "Mathematical Alphanumeric Symbols"
    UnicodeSubRange(90) = "Private Use (Plane 15)"

End Sub

Public Function EnumFontFamExProc(ByRef lpELFX As ENUMLOGFONTEX, _
    ByRef lpNTME As NEWTEXTMETRICEX, ByVal lFontType As Long, _
    ByVal lParam As Long) As Long

    Dim ctr As Integer
    Dim sFaceName As String

    sFaceName = ""

    For ctr = 1 To LF_FACESIZE
        If lpELFX.elfLogFont.lfFaceName(ctr) = 0 Then
            Exit For
        Else
            sFaceName = sFaceName & Chr(lpELFX.elfLogFont.lfFaceName(ctr))
        End If
    Next

    Form1.List1.AddItem sFaceName

    If FontCtr > 0 Then
        ReDim Preserve Signature(0 To 1, 0 To FontCtr + 1)
    Else
        ReDim Signature(0 To 1, 0 To 0)
    End If

    Signature(0, FontCtr) = sFaceName
    Signature(1, FontCtr) = lpNTME.ntmFontSig.fsUsb
    FontCtr = FontCtr + 1

    EnumFontFamExProc = 1

End Function

Public Sub PopulateList2()

    Dim vSig As Variant
    Dim p As Integer
    Dim q As Integer
    Dim ctr As Integer

    Form1.List2.Clear

    For ctr = 0 To UBound(Signature, 2)
        If Signature(0, ctr) = Form1.List1.Text Then Exit For
    Next

    vSig = Signature(1, ctr)

    For ctr = 0 To MAXSUBRANGELISTEDHERE
        p = Int(ctr / 32)
        q = ctr Mod 32

        If q <> 31 Then
            If vSig(p) And 2 ^ q Then
                Form1.List2.AddItem UnicodeSubRange(ctr)
            End If
        Else
            If vSig(p) < 0 Then
                Form1.List2.AddItem UnicodeSubRange(ctr)
            End If
        End If
    Next

End Sub

WinAPI : Enumerating Installed Fonts

Jalaj — Wed, 23 May 2007 14:10:23 +0000

Now after the last post WinAPI : The Font Object, let's see what all fonts are installed on your system. We would do this with the help of EnumFontFamiliesEx function. Once you have called he function, you receive each of the (matching) font's details vide callback function EnumFontFamExProc.

The EnumFontFamiliesEx function as defined below takes the first parameter the handle to the Device Context. The Second parameter that it takes is the pointer to the LOGFONT structure, already described in the last post. This parameter is used by the system to determine which of the font's details you require, passing a Null provides you with details of all of them. The next parameter that it takes is the pointer to the EnumFontFamExProc callback function. Next parameter lParam is the application defined value which is returned to the callback function with the other details. Last parameter is unused and should be passed as Zero.

Public Declare Function EnumFontFamiliesEx Lib "gdi32" Alias "EnumFontFamiliesExA" ( _
	ByVal hDC As Long, lpLogFont As LOGFONT, ByVal lpEnumFontProc As Long, _
	ByVal lParam As Long, ByVal dw As Long) As Long

Now lets see what the EnumFontFamExProc callback function looks like.

Public Function EnumFontFamExProc(ByRef lpELFX As ENUMLOGFONTEX, _
	ByRef lpNTME As NEWTEXTMETRICEX, ByVal lFontType As Long, _
	ByVal lParam As Long) As Long
. . .
. . .
. . .
End Function

The first parameter is the pointer to the ENUMLOGFONTEX structure giving logical font data, detailed later. The second parameter is the pointer to the NEWTEXTMETRICEX structure that gives the physical font data, also detailed later. Next parameter is FontType which can be equal to one of the constants as defined below. Last parameter is the lParam as was passed while calling the EnumFontFamiliesEx function.

Public Const RASTER_FONTTYPE = 1
Public Const DEVICE_FONTTYPE = 2
Public Const TRUETYPE_FONTTYPE = 4

ENUMLOGFONTEX structure as defined below contains a LOGFONT structure, Full name of the font (a Null terminated string, 64 bytes), a Null terminated string of 32 bytes specifying the style of the font, and a Null terminated string of 32 bytes specifying the script or character set of the font.

Public Const LF_FACESIZE = 32
Public Const LF_FULLFACESIZE = 64

Public Type ENUMLOGFONTEX
        elfLogFont As LOGFONT
        elfFullName(LF_FULLFACESIZE) As Byte
        elfStyle(LF_FACESIZE) As Byte
        elfScript(LF_FACESIZE) As Byte
End Type

The NEWTEXTMETRICEX structure as defined below itself consolidates the other two structures NEWTEXTMETRIC and FONTSIGNATURE also defined below.

Public Type NEWTEXTMETRICEX
        ntmTm As NEWTEXTMETRIC
        ntmFontSig As FONTSIGNATURE
End Type

Public Type NEWTEXTMETRIC
        tmHeight As Long
        tmAscent As Long
        tmDescent As Long
        tmInternalLeading As Long
        tmExternalLeading As Long
        tmAveCharWidth As Long
        tmMaxCharWidth As Long
        tmWeight As Long
        tmOverhang As Long
        tmDigitizedAspectX As Long
        tmDigitizedAspectY As Long
        tmFirstChar As Byte
        tmLastChar As Byte
        tmDefaultChar As Byte
        tmBreakChar As Byte
        tmItalic As Byte
        tmUnderlined As Byte
        tmStruckOut As Byte
        tmPitchAndFamily As Byte
        tmCharSet As Byte
        ntmFlags As Long
        ntmSizeEM As Long
        ntmCellHeight As Long
        ntmAveWidth As Long
End Type

Public Type FONTSIGNATURE
        fsUsb(4) As Long
        fsCsb(2) As Long
End Type

The members in the NEWTEXTMETRIC structure are as under:
tmHeight - Specifies the height (ascent + descent) of characters.
tmAscent - Specifies the ascent (units above the base line) of characters.
tmDescent - Specifies the descent (units below the base line) of characters.
tmInternalLeading - Specifies the amount of leading (space) inside the bounds set by the tmHeight member. Accent marks and other diacritical characters, if any, occurs in this area.
tmExternalLeading - Specifies the amount of extra leading (space) that the application adds between rows. This area is outside the font, and hence can contain no marks.
tmAveCharWidth - Specifies the average width of characters in the font (generally defined as the width of the letter x). This value does not include overhang required for bold or italic characters.
tmMaxCharWidth - Specifies the width of the widest character in the font.
tmWeight - Specifies the weight of the font.
tmOverhang - Specifies the extra width per string that may be added to some synthesized fonts. When synthesizing some attributes, such as bold or italic, graphics device interface (GDI) or a device may have to add width to a string on both a per-character and per-string basis. tmDigitizedAspectX - Specifies the horizontal aspect of the device for which the font was designed.
tmDigitizedAspectY - Specifies the vertical aspect of the device for which the font was designed. The ratio of the tmDigitizedAspectX and tmDigitizedAspectY members is the aspect ratio of the device for which the font was designed.
tmFirstChar - Specifies the value of the first character defined in the font.
tmLastChar - Specifies the value of the last character defined in the font.
tmDefaultChar - Specifies the value of the character to be substituted for characters that are not in the font.
tmBreakChar - Specifies the value of the character to be used to define word breaks for text justification.
tmItalic - Specifies an italic font if it is nonzero.
tmUnderlined - Specifies an underlined font if it is nonzero.
tmStruckOut - Specifies a strikeout font if it is nonzero.
tmPitchAndFamily - Specifies the pitch and family of the selected font. For details see the LOGFONT structure in post WinAPI : The Font Object.
tmCharSet - Specifies the character set of the font.
ntmFlags - Specifies whether the font is italic, underscored, outlined, bold, and so forth. May be any reasonable combination of the following values as defined below.

Const NTM_ITALIC = 1
Const NTM_BOLD = 32
Const NTM_REGULAR = 256
Const NTM_NONNEGATIVE_AC = 65536 	' Win2000/XP
Const NTM_PS_OPENTYPE = 131072	' Win2000/XP
Const NTM_TT_OPENTYPE = 262144	' Win2000/XP
Const NTM_MULTIPLEMASTER = 524288	' Win2000/XP
Const NTM_TYPE1 = 1048576 		' Win2000/XP
Const NTM_DSIG = 2097152		' Win2000/XP

ntmSizeEM - Specifies the size of the em square for the font. This value is in notional units (that is, the units for which the font was designed).
ntmCellHeight - Specifies the height, in notional units, of the font. This value should be compared with the value of the ntmSizeEM member.
ntmAvgWidth - Specifies the average width of characters in the font, in notional units. This value should be compared with the value of the ntmSizeEM member.

The FONTSIGNATURE structure contains two members :
fsUsb - an array of four longs, making up for 128 bits that identify upto 126 Unicode Subranges as defined in ISO 10646 standard.
fsCsb - an array of two longs, making up for 64 bits that identifies Character sets or Code Page.

Next post(s) on the WinAPI functions will demonstrate practical usage of these functions...

WinAPI : DrawText & DrawTextEx

Jalaj — Wed, 09 May 2007 06:54:02 +0000

My last post on the WinAPI series was WinAPI : Displaying Text. Let's get ahead with more WinAPI functions starting with DrawText and DrawTextEx functions.

Public Declare Function DrawText Lib "user32" Alias "DrawTextA" ( _
	ByVal hdc As Long, ByVal lpStr As String, ByVal nCount As Long, _
	lpRect As RECT, ByVal wFormat As Long) As Long

Public Type RECT
        Left As Long
        Top As Long
        Right As Long
        Bottom As Long
End Type

While the TextOut function required you to specify only the top-left co-ordinates to write out the text, DrawText requires you to specify the rectangular area where you need to draw and also expects you to specify formatting options as to how text should be aligned or so within the rectangle. The first parameter is takes is the handle to the input context, second the string that you need to print out, next the number of characters from the string to be printed out. The next two parameters are the pointer to the RECT structure and the formatting option (which may be one or more of constants defined below) respectively.

Const DT_LEFT = &H0
Const DT_TOP = &H0
Const DT_CENTER = &H1
Const DT_RIGHT = &H2
Const DT_VCENTER = &H4
Const DT_BOTTOM = &H8

The above constants may be used for vertical/horizontal alignment of the text (default Top-Left). Vertical alignment can be modified only in case of SingleLines (as defined below).

Const DT_WORDBREAK = &H10

Using the constant above ensures that line is automatically broken between words. In absence of this constant the line would break only when encounter carriage return and line feed sequence, and all words that moved out of rectangular area being clipped.

Const DT_SINGLELINE = &H20

Using constant above makes the text to display in a single line. Even the carriage return line feed sequence are not considered for moving to next line.

Const DT_EXPANDTABS = &H40
Const DT_TABSTOP = &H80

DT_EXPANDTABS causes Tab characters to be shown as a sequence of eight (default) space characters. This default value can be modified using constant DT_TABSTOP (am unsure of how? Inputs welcome)

Const DT_NOCLIP = &H100

Constant above ensures that the words are not clipped if they extend beyond the rectangle defined.

Const DT_EXTERNALLEADING = &H200

Leading is the vertical space that separates the two lines. Normally the leading as defined in the font is not considered for drawing the text by the function. Including the constant as above it to be included in drawing the text.

Const DT_CALCRECT = &H400

The above constant can be used to calculate the optimum size of the rectangle that would be required to print out the text. Using this constant doesnot cause the text to be printed but instead modifies the RECT structure passed to the function appropriately.

Const DT_NOPREFIX = &H800
Const DT_HIDEPREFIX = &H100000	'WinXP onwards
Const DT_PREFIXONLY = &H200000	'WinXP onwards

By default the DrawText function considers presence of and ampersand ('&') as a directive to underline the character that follows, while '&' itself is not drawn. In order to display '&' you need to give '& &'. Using the constant as above turns off this nature and draws '&' as it is. The other two constants that were included in WindowsXP. DT_HIDEPREFIX instructs the function to refrain from showing any underlined characters so existence of an '&' which otherwise would have shown character following it as underlined (or shown itself as it is if DT_NOPREFIX used) will neither show the '&' noor the underlining of the next character. DT_PREFIXONLY causes the function to display nothing other than the Underline itself (at location where the character that it underlined would have appeared.

Const DT_INTERNAL = &H1000

"Uses the system font to calculate text metrics." (as described in MSDN, unsure of what it actually meant)

Const DT_EDITCONTROL = &H2000

Normally for a multiline text if the rectangle is not large enough to accommodate all text a few lines moving outside the rectangle are clipped and the clipping is done without checking in case a line at the bottom is partially visible. Using this constant ensures that such partially visible lines are not shown at all.

Const DT_END_ELLIPSIS = &H8000
Const DT_WORD_ELLIPSIS = &H40000
Const DT_PATH_ELLIPSIS = &H4000

The above three constants are useful if the string is large enough to fit into the rectangle, where it truncates the string adding ellipses '...' (at the end for the first two and in-between for the last). The three constants vary in the manner the addition of ellipses is done. For DT_END_ELLIPSIS it truncates all complete words that move out of rectangle area and adds the ellipses at the end. In this case the ellipses may not always be visible as the last word after which the ellipses occur may itself be clipped by the bounding rectangle. DT_END_ELLIPSIS ensures that the ellipses are visible even if the last word itself needs to be partially-truncated for achieving the same. DT_PATH_ELLIPSIS is useful for showing the strings containing file paths (You may find this being applied in a Anti-Virus or similar software), where it is ensured that most of the filename is kept intact and the ellipses is added in midst of the string to hide part of the folder structure.

Const DT_MODIFYSTRING = &H10000

The above constant ensures that the string itself is modified to match it with that visible within the rectangle.

Const DT_RTLREADING = &H20000

Useful for rendering bi-directional text in Arabic and Hebrew fonts.

Const DT_NOFULLWIDTHCHARBREAK = &H80000

For Win98 onwards. Ensures that line break does not occur between Double Byte Character String (DBCS).

DrawTextEx function adds one for input parameter which is a pointer to the DRAWTEXTPARAMS structure defined below allowing you to configure the Character length for a Tab, Right and Left Margin that should be left while drawing within the rectangle. All other details remain the same as with DrawText function.

Public Declare Function DrawTextEx Lib "user32" Alias "DrawTextExA" ( _
	ByVal hdc As Long, ByVal lpStr As String, ByVal nCount As Long, _
	lpRect As RECT, ByVal wFormat As Long, _
	lpDrawTextParams As DRAWTEXTPARAMS) As Long

Public Type DRAWTEXTPARAMS
	cbSize As Long
	iTabLength As Long
	iLeftMargin As Long
	iRightMargin As Long
	uiLengthDrawn As Long
End Type

WinAPI : Displaying Text

Jalaj — Mon, 12 Mar 2007 11:46:42 +0000

After getting a feel of how Pens and Brushes are used for drawing on a Device Context, let's get on to displaying texts on a Device Context.

The most basic function for the purpose is the TextOut. The function takes handle to the device context as the first parameter. The next two parameters are the X and Y co-ordinates of the reference point that system uses to align the string. The next parameter is the pointer to the string that is to be displayed and the last parameter is the number of characters in the string. Function returns non-zero if it succeeds otherwise a zero.

Private Declare Function TextOut Lib "gdi32" Alias "TextOutA" ( _
    ByVal hDC As Long, ByVal x As Long, ByVal y As Long, _
    ByVal lpString As String, ByVal nCount As Long) As Long

By default, the text is displayed Top-Left with reference to the co-ordinates passed. This is the default behaviour of the device context, however can be changed using the SetTextAlign function. Further the current position on the device context is neither used nor updated by the TextOut function, this behaviour however can also be modified using SetTextAlign function.

The function takes first parameter the handle to the device context and the next parameter is one or more of the constants defined below while will determine the alignment of texts that would be drawn next time.

Private Declare Function SetTextAlign Lib "gdi32" ( _
    ByVal hdc As Long, ByVal wFlags As Long) As Long

Const TA_LEFT = 0
Const TA_TOP = 0
Const TA_NOUPDATECP = 0
Const TA_UPDATECP = 1
Const TA_RIGHT = 2
Const TA_CENTER = 6
Const TA_BOTTOM = 8
Const TA_BASELINE = 24
Const TA_MASK = (TA_BASELINE + TA_CENTER + TA_UPDATECP)

Similarly SetTextColor function can be used to change the text color associated with the device context. The function takes handle to the device context as the first parameter. The second parameter is the Color reference calculated using RGB macro.

Private Declare Function SetTextColor Lib "gdi32" Alias "SetTextColor" ( _
    ByVal hdc As Long, ByVal crColor As Long) As Long

Similar posts on Technorati : Visual Basic, Programming, Microsoft, Windows, WinAPI, GDI32, Text, Functions, TextOut, SetTextAlign, SetTextColor,